Hilfe bei der Berechnung von Stromverbrauchswerten gesucht

patrick31698

Hallo,
ich habe gerade mal die channels meiner tasmota geflashten Steckdosen erweitert.
und mich auf die Suche nach Stromfressern begeben. Einen habe ich schon gefunden.

Ich würde jetzt gerne die Verbrauchswerte in bestimmten Zeitabschnitten (wöchentlich, monatlich, jährlich ? )
in der Sitemap darstellen lassen. Ich denke, das interessiert gerade jetzt eine Menge Leute. Vielleicht kann der @horschte mal wieder?
Als Persistence verwende ich rrd4j

Code

Thing topic Gosund_SP1_1 "Gosund_SP1_1" @ "mqtt" 
{Channels:
Type switch:Gosund_SP1_1 [stateTopic="stat/Gosund_SP1_1/POWER", commandTopic="cmnd/Gosund_SP1_1/POWER"]
Type number : Power        [stateTopic="tele/Gosund_SP1_1/SENSOR", transformationPattern="JSONPATH:$.ENERGY.Power"]
Type number : Today        [stateTopic="tele/Gosund_SP1_1/SENSOR", transformationPattern="JSONPATH:$.ENERGY.Today"]
Type number : Yesterday    [stateTopic="tele/Gosund_SP1_1/SENSOR", transformationPattern="JSONPATH:$.ENERGY.Yesterday"]
Type number : Total        [stateTopic="tele/Gosund_SP1_1/SENSOR", transformationPattern="JSONPATH:$.ENERGY.Total"]
}

Code

Switch    Gosund_SP1_1    "Fernseher"  <poweroutlet>   (gEG_Wohnzimmer) {channel="mqtt:topic:MosquittoMqttBroker:Gosund_SP1_1:Gosund_SP1_1"}
Number    SP1_1_Power     "aktuelle Leistung [%.1f W]" (gVerbrauch)  {channel="mqtt:topic:MosquittoMqttBroker:Gosund_SP1_1:Power"}
Number    SP1_1_Yesterday "gestriger Verbrauch [%.3f kWh]"   {channel="mqtt:topic:MosquittoMqttBroker:Gosund_SP1_1:Yesterday"}
Number    SP1_1_Total     "gesamter Verbrauch"   {channel="mqtt:topic:MosquittoMqttBroker:Gosund_SP1_1:Total"}

Danke schon einmal
Gruß
Patrick

horschte

kurze frage...bin gerade dabei was fertig zu machen. kommen ggf noch andere steckdosen dazu und du brauchst eine gesamtübersicht aller verbraucher oder geht es nur um diese steckdose.

patrick31698

Im Moment ist es nur diese eine. Bei mir ist vieles nur Spielerei. Aber wer weiß wo es hin geht.

Ich habe noch ein paar andere Steckdosen. Vielleicht gleich die grosse Lösung?

horschte

keine ahnung was du möchtest. wenn dich dein stromverbrauch grundsätzlich interessiert, dann nutze gleich eine gesamtlösung anstatt einzelne steckdosen. bspw shelly3em. der ist mit hilfe eines elektrikers sehr unkompliziert anzubringen. dann haste du gleich deinen gesamtverbrauch im haus/wohnung.
ich will mir nur doppelte arbeit ersparen...daher die nachfrage.

patrick31698

Dann ist die Antwort nein. Es bleibt bei einzelnen Zwischensteckdosen.

Für den Gesamtverbrauch liebäugel ich im Moment mit einem IR Lesekopf. Blöderweise habe ich keine Steckdose in der Nähe des Zählers.

horschte

Zitat von patrick31698

Für den Gesamtverbrauch liebäugel ich im Moment mit einem IR Lesekopf. Blöderweise habe ich keine Steckdose in der Nähe des Zählers.

warum das denn? ein shelly passt in jeden sicherungskasten und es wird keine steckdose gebraucht.

patrick31698

Ich bin kein Elektriker!

und ich weiß nicht, ob das bei meiner Installation hier irgendwelchen Sinn macht. Das Haus ist aus den 70ern und bietet nur sehr beschränkte Möglichkeiten.
Einen ganz einfachen Shelly habe ich vor kurzem gekauft, weil ich mein Garagentor smart machen wollte. das scheitert daran, dass ich keine WLAN Empfang in der Garage habe.

horschte

auf gehts....sieht zwar viel aus aber im grunde musst du da nie mehr was ändern. neue geräte müssen lediglich in die beiden später angesprochenen gruppen.

items (deine tv steckdose ist da auch ganz unten drin. also pass auf, dass du deine bisherigen einträge der steckdose löscht)

Code

// Der Gesamtverbrauch jedes neuen Gerätes muss in die Gruppe "Verbrauch_gesamt", der aktuelle Verbrauch jedes Gerätes muss in die Gruppe "Verbrauch_aktuell"


// Verbrauchergruppen
Group:Number:SUM  Verbrauch_gesamt      "Stromverbrauch gesamt [%.2f kWh]"               <energy>
Group:Number:SUM  Verbrauch_aktuell     "Stromverbrauch aktuell [%.0f Wh]"              <energy>


// Speicherung der Zeitfenster
Group Verbrauchsberechnung


// Berechnungen Verbrauch
Number                Verbrauch_gesamt_Tag            "Verbrauch heute [%.2f kWh]"          <energy>
Number                Verbrauch_gesamt_gestern        "Verbrauch gestern [%.2f kWh]"        <energy>    (Verbrauchsberechnung)
Number                Verbrauch_gesamt_Woche          "Verbrauch Woche [%.2f kWh]"          <energy>
Number                Verbrauch_letzte_Woche          "Verbrauch letzte Woche [%.2f kWh]"   <energy>    (Verbrauchsberechnung)
Number                Verbrauch_gesamt_Monat          "Verbrauch Monat [%.2f kWh]"          <energy>
Number                Verbrauch_letzten_Monat         "Verbrauch letzten Monat [%.2f kWh]"  <energy>    (Verbrauchsberechnung)
Number                Verbrauch_gesamt_Jahr           "Verbrauch Jahr [%.2f kWh]"           <energy>
Number                Verbrauch_Tag_Durchschnitt      "Tagesverbrauch Ø [%.2f kWh]"         <energy>    (Verbrauchsberechnung)


Number                Verbrauch_gesamt_Tag_Preis      "Stromkosten heute [%.2f €]"          <price>
Number                Verbrauch_gesamt_gestern_Preis  "Stromkosten gestern [%.2f €]"        <price>     (Verbrauchsberechnung)
Number                Verbrauch_gesamt_Woche_Preis    "Stromkosten Woche [%.2f €]"          <price>
Number                Verbrauch_letzte_Woche_Preis    "Stromkosten letzte Woche [%.2f €]"   <price>     (Verbrauchsberechnung)
Number                Verbrauch_gesamt_Monat_Preis    "Stromkosten Monat [%.2f €]"          <price>
Number                Verbrauch_letzten_Monat_Preis   "Stromkosten letzten Monat [%.2f €]"  <price>     (Verbrauchsberechnung)
Number                Verbrauch_gesamt_Jahr_Preis     "Stromkosten Jahr [%.2f €]"           <price>


// Steckdose Fernseher
Switch    Gosund_SP1_1    "Fernseher"                       <poweroutlet>   (gEG_Wohnzimmer)                        {channel="mqtt:topic:MosquittoMqttBroker:Gosund_SP1_1:Gosund_SP1_1"}
Number    SP1_1_Power     "aktuelle Leistung [%.1f W]"                      (Verbrauch_aktuell)                     {channel="mqtt:topic:MosquittoMqttBroker:Gosund_SP1_1:Power"}
Number    SP1_1_Yesterday "gestriger Verbrauch [%.3f kWh]"                                                          {channel="mqtt:topic:MosquittoMqttBroker:Gosund_SP1_1:Yesterday"}
Number    SP1_1_Total     "gesamter Verbrauch"                              (Verbrauch_gesamt)                      {channel="mqtt:topic:MosquittoMqttBroker:Gosund_SP1_1:Total"}

Alles anzeigen

rules
WICHTIG!!! ...die aufgeführte zeile val strompreis = 0.28 MUSS in die allererste zeile deiner *.rules datei. zusätzlich natürlich auf deinen strompreis anpassen ....den rest kannst du da plazieren wo du willst

Code

// Strompreis in Cent
val strompreis = 0.28




rule "Verbrauchsberechnungen Zeiträume"
    when
        Item Verbrauch_gesamt changed
    then
        val  ZonedDateTime   zdt = ZonedDateTime.now()
        var  ZonedDateTime   start_of_day = zdt.toLocalDate().atStartOfDay(zdt.getZone())
        var  ZonedDateTime   start_of_week = zdt.with(DayOfWeek.MONDAY).toLocalDate().atStartOfDay(zdt.getZone())
        var  ZonedDateTime   start_of_month = zdt.withDayOfMonth(1).toLocalDate().atStartOfDay(zdt.getZone())
        var  ZonedDateTime   start_of_year = zdt.withDayOfYear(1).toLocalDate().atStartOfDay(zdt.getZone())


        var  heute = Verbrauch_gesamt.deltaSince(start_of_day) as Number
        var  woche = Verbrauch_gesamt.deltaSince(start_of_week) as Number
        var  monat = Verbrauch_gesamt.deltaSince(start_of_month) as Number
        var  jahr = Verbrauch_gesamt.deltaSince(start_of_year) as Number


            Verbrauch_gesamt_Tag.postUpdate(heute)
            Verbrauch_gesamt_Woche.postUpdate(woche)
            Verbrauch_gesamt_Monat.postUpdate(monat)
            Verbrauch_gesamt_Jahr.postUpdate(jahr)
end


// Stromkostenberechnungen für festgelegte Zeiträume


rule "Stromkostenberechnung heute"
    when 
        Item Verbrauch_gesamt_Tag changed
    then
        val verbrauch_heute = Verbrauch_gesamt_Tag.state as Number
            Verbrauch_gesamt_Tag_Preis.postUpdate(verbrauch_heute * strompreis) 
end


rule "Stromkostenberechnung Woche"
    when 
        Item Verbrauch_gesamt_Woche changed
    then
        val verbrauch_woche = Verbrauch_gesamt_Woche.state as Number
            Verbrauch_gesamt_Woche_Preis.postUpdate(verbrauch_woche * strompreis) 
end


rule "Stromkostenberechnung Monat"
    when 
        Item Verbrauch_gesamt_Monat changed
    then
        val verbrauch_monat = Verbrauch_gesamt_Monat.state as Number
            Verbrauch_gesamt_Monat_Preis.postUpdate(verbrauch_monat * strompreis) 
end


rule "Stromkostenberechnung Jahr"
    when 
        Item Verbrauch_gesamt_Jahr changed
    then
        val verbrauch_jahr = Verbrauch_gesamt_Jahr.state as Number
            Verbrauch_gesamt_Jahr_Preis.postUpdate(verbrauch_jahr * strompreis) 
end


rule "Stromkostenberechnung gestern und letzte woche"
    when
    Time cron "50 59 23 * * ?" 
    then
        var tag = now.getDayOfWeek.getValue()
            Verbrauch_gesamt_gestern.postUpdate(Verbrauch_gesamt_Tag.state)
            Verbrauch_gesamt_gestern_Preis.postUpdate(Verbrauch_gesamt_Tag_Preis.state)
            if(tag == 7) {
                Verbrauch_letzte_Woche.postUpdate(Verbrauch_gesamt_Woche.state)
                Verbrauch_letzte_Woche_Preis.postUpdate(Verbrauch_gesamt_Woche_Preis.state)
            }
end


rule "Stromkostenberechnung letzten monat"
    when
        Time cron "50 59 23 L * ? *" 
    then
        Verbrauch_letzten_Monat.postUpdate(Verbrauch_gesamt_Monat.state)
        Verbrauch_letzten_Monat_Preis.postUpdate(Verbrauch_gesamt_Monat_Preis.state)
end


rule "Stromkostenberechnung durchschnitt"
    when 
        Item Verbrauch_gesamt_gestern changed 
    then
        var Number Tagesdurchschnitt = Verbrauch_gesamt_gestern.averageSince(now.minusYears(20))
        Verbrauch_Tag_Durchschnitt.postUpdate(Tagesdurchschnitt)
end

Alles anzeigen

sitemap beispiel
wichtig! es werden nur werte für zeitfenster angezeigt die komplett begonnen oder komplett abgeschlossen sind. monat aktuell kann bspw erst wenn der neue monat beginnt angezeigt werden, letzter monat erst wenn ein monat abgeschlossen ist usw usw. es müssen also vollständige datensätze der jeweiligen zeiträume erfasst sein. wenn du das heute integrierst, hast du also bspw ab morgen 0 uhr die ersten verbrauchsanzeigen und preise für den laufenden tag. aus dem grunde auch "visibility" in der sitemap, um items ohne wert auszublende

Code

Text item=Verbrauch_aktuell   {
	Frame label="Stromverbrauch"{
		Text item=Verbrauch_aktuell		
		Text item=Verbrauch_gesamt_Tag
		Text item=Verbrauch_gesamt_gestern			visibility=[Verbrauch_gesamt_gestern != NULL]
		Text item=Verbrauch_Tag_Durchschnitt		visibility=[Verbrauch_Tag_Durchschnitt != NULL]
		Text item=Verbrauch_gesamt_Woche			visibility=[Verbrauch_gesamt_Woche != NULL]
		Text item=Verbrauch_letzte_Woche			visibility=[Verbrauch_letzte_Woche != NULL]
		Text item=Verbrauch_gesamt_Monat			visibility=[Verbrauch_gesamt_Monat != NULL]
		Text item=Verbrauch_letzten_Monat			visibility=[Verbrauch_letzten_Monat != NULL]
		Text item=Verbrauch_gesamt_Jahr				visibility=[Verbrauch_gesamt_Jahr != NULL]
	} 
	Frame label="Stromkosten"{
		Text item=Verbrauch_gesamt_Tag_Preis		visibility=[Verbrauch_gesamt_Tag_Preis != NULL]
		Text item=Verbrauch_gesamt_gestern_Preis	visibility=[Verbrauch_gesamt_gestern_Preis != NULL]  
		Text item=Verbrauch_gesamt_Woche_Preis		visibility=[Verbrauch_gesamt_Woche_Preis != NULL]
		Text item=Verbrauch_letzte_Woche_Preis		visibility=[Verbrauch_letzte_Woche_Preis != NULL]
		Text item=Verbrauch_gesamt_Monat_Preis		visibility=[Verbrauch_gesamt_Monat_Preis != NULL]
		Text item=Verbrauch_letzten_Monat_Preis		visibility=[Verbrauch_letzten_Monat_Preis != NULL]
		Text item=Verbrauch_gesamt_Jahr_Preis		visibility=[Verbrauch_gesamt_Jahr_Preis != NULL]
	} 		
}

Alles anzeigen

folgende gruppen und gruppenwerte müssen in deine persist datei.
die einträge mit und ohne * sind korrekt so, da in einigen fällen auch der gruppenwert selbst gespeichert werden soll

Code

Strategies {
	everyMinute : "0 * * * * ?"
	everyhour : "0 0 0/1 1/1 * ? *"
}


Items {
	Verbrauch_gesamt*, Verbrauch_gesamt, Verbrauch_aktuell*, Verbrauch_aktuell, Verbrauchsberechnung*	 : strategy =  restoreOnStartup, everyChange, everyhour
}

falls fehler auftreten (was bei so umfangreichen berechnungen ja schnell durch tippfehler o.ä. passieren kann) ----> [definition='1','0']log[/definition] mitsenden

wichtig: die rules gehen davon aus, dass deine geräte einen kwh-wert für tagesverbrauch und gesamtverbrauch liefern (wie bspw deine steckdose). solltest du ein anderes gerät in die gruppen Verbrauch_gesamt mit aufnehmen wollen prüfe zuerst ob das da ebenfalls so ist. ansonsten wird deine datenbank verfälscht. für ein gerät welche wh statt kwh liefert müsste erst eine kleine umrechnung gemacht werden.

patrick31698

klappt doch

horschte

na dann solltest du heute bereits aktuellen verbrauch + gesamtverbrauch heute + preis heute sehen.

patrick31698

Ja

horschte

ab morgen sollte dann der gestrige tag. also heute sichtbar werden, ab montag dann der wochenwert, ab dienstag der monatswert.

Kaloschke

Hallo Horschte,

Vielen, vielen Dank. Das erspart mir ne Menge Arbeit!
Habe deinen Code an meinen Shelly PLUG S angepasst. Klappt soweit alles prima.
Bis auf eine Sache. Die Anzeige der Sitemap aktualisiert sich nicht automatisch. Erst wenn ich die Seite neu lade, erscheinen die neuen Werte.
Hast Du dafür einen Tipp?

Viele Grüße

Kaloschke

Seltsam. Auf dem Handy wird aktualisiert, im Browser nicht

horschte

Starte mal openhab komplett neu. Das von dir beschriebene Problem hat nichts mit der Integration zu tun

Kaloschke

Hatte ich schon -und dachte ich mir schon.
Habe jetzt auch den Cache gelöscht. Leider alles weiter so wie oben beschrieben.

Kaloschke

"Problem" gelöst. Der Name der Sitemap in meiner energy.sitemap stimmte nicht mit dem Dateinamen überein.
Hatte ich schon das ein oder andere Mal, bin aber wohl nicht lernfähig :-.(

Vielen Dank noch mal.

Kaloschke

Doch noch eine Frage:

Mein Gesamtverbrauch wird angezeigt, aber in der rule "Verbrauchsberechnungen Zeiträume" bekomme ich den Fehler

Code

java.lang.RuntimeException: Cannot create a resource for 'java:/Objects/java.time.LocalDate'; a registered resource factory is needed

Muss ich irgendwo noch was zu date/time o.ä. einbinden?

patrick31698

Ich habe mal gesucht. Ich habe da noch nicht einmal gefährliches Halbwissen. Die paar Sachen, die ich da gefunden habe, deuten für mich auf ein Problem mit der Datenbank hin.
Das habe ich mit @horschte anderweitig geklärt.

horschte

nein. das sollte alles einfach so laufen. welche openhab und welche java version? was für eine datenbank?

Hilfe bei der Berechnung von Stromverbrauchswerten gesucht

Jetzt mitmachen!

Benutzer online in diesem Thema