flipper tastatur

the ratman

uij, vielen dank fürs lob!
wobei es ja eher ein "wir" ist. ohne seppl1 gäbs das projekt ja nicht wirklich. dann wärs nämlich einfach nur ein luftiger golf-schläger *g*
so kann ich hier zeigen, was ein kranker geist mit unterstützung anderer schaffen kann ... in diesem forum wäre so viel platz für andere leute mit kranken ideen!

video ... mal schauen. jetzt muss dass ding ja erst mal unfallfrei rennen.

the ratman

hmm,

langsam amch ich mir sorgen um meinen @Seppl1 - ausgewandert und bei münchen verirrt? *g*

don

Moin,
ich mache auch gerade etwas in dem Thema.
Den Farfalla will gerade ein Kunde restaurieren und ich mache die durchleuchtete Rückwand neu:

Ist vor allem Grafikarbeit. Den Druck mache ich dann hinter Acryl mit einem UV-Plattendrucker. Der kann auch weiß.

the ratman

lieferst ein vorher/nachher dann mal?

Seppl1

Keine Sorge, mich gibt's noch. War nur die letzten Tage ziemlich beschäftigt bzw. wollte in meiner freien Zeit dann nicht noch mehr vor dem Computer sitzen.

Kannst du die Schubser von links/rechts auf einzelne Tasten legen? In dem Fall sollte es mit dem folgenden Code funktionieren.

Wenn du die Tasten vergeben hast, musst du in Zeile 18-23 die jeweiligen Keys für Haue von links/rechts/vorne... eintragen. Wenn eine Richtung nicht verwendet wird, sollte der Wert auf 0 gesetzt werden.
In Zeile 47-52 müssen Referenzwert und Grenzwert für die jeweilige Achse gesetzt werden. Um das besser zu bestimmen kannst du den zweiten Code weiter unten verwenden, damit der Sensor dir jede Malträtierung per serieller Schnittstelle berichtet. Genauer gesagt wird er ständig den aktuellen Sensorwert ausgeben und wenn getriggert wird kommt eine entsprechende Meldung.

C

#include <Keyboard.h>
/*  
flipper gross
*/
// ---------------------------------
// KEYS
#define RS_KEY 0x85
#define LS_KEY 0x81
#define R_KEY 0xB0
#define EC_KEY 0xB1
#define XX_KEY 0x00
#define UP_KEY 0xDA
#define RT_KEY 0xD7
#define LF_KEY 0xD8
#define DN_KEY 0xD9
#define SP_KEY 0x20
#define SENSE_X_POSITIVE_KEY SP_KEY
#define SENSE_X_NEGATIVE_KEY SP_KEY
#define SENSE_Y_POSITIVE_KEY SP_KEY
#define SENSE_Y_NEGATIVE_KEY 0
#define SENSE_Z_POSITIVE_KEY 0
#define SENSE_Z_NEGATIVE_KEY 0


// STRINGS
#define N1_STRING "BUCHSTABENFOLGE1"
#define N2_STRING "BUCHSTABENFOLGE2"
// PINS
#define RS_PIN 2
#define LS_PIN 3
#define R1_PIN 4
#define N1_PIN 5
#define N2_PIN 6
#define R2_PIN 7
#define EC_PIN 8
#define XX_PIN 9
#define SENSE_X_PIN A3
#define SENSE_Y_PIN A2
#define SENSE_Z_PIN A1
#define UP_PIN 15
#define RT_PIN 14
#define LF_PIN 16
#define DN_PIN 10


// Sensor values
// Referenzwert ist der Wert in Ruhe, Threshold ab welchem Ausschlag es reagieren soll
#define SENSE_X_REF 0
#define SENSE_X_THRESHOLD 10
#define SENSE_Y_REF 0
#define SENSE_Y_THRESHOLD 10
#define SENSE_Z_REF 0
#define SENSE_Z_THRESHOLD 10


// ---------------------------------


// Button helper class for handling press/release and debouncing
class button {
  public:
    const char key;
    const uint8_t pin;
    button(uint8_t k, uint8_t p) : key(k), pin(p) {}
    void press(boolean state) {
      if (state == pressed || (millis() - lastPressed  <= debounceTime)) {
        return; // Nothing to see here, folks
      }
      lastPressed = millis();
      state ? Keyboard.press(key) : Keyboard.release(key);
      pressed = state;
    }
    void update() {
      press(!digitalRead(pin));
    }
  private:
    const unsigned long debounceTime = 30;
    unsigned long lastPressed = 0;
    boolean pressed = 0;
};


class sensor {
  public:
    const char poskey;
    const char negkey;
    const int pin;
    const int ref;
    const int minBump;
    sensor(int pk, int nk, int p, int r, int mB) : poskey(pk), negkey(nk), pin(p), ref(r), minBump(mB){}
    int readraw() {
      return analogRead(pin);
    }
    bool hit() {
      int a = readraw();
      posHit = a > ref;
      return abs(a - ref) > minBump;
    }
    void tilt() {
      if (!(hit()) || (millis() - lastHit <= debounceTime)) {return;}
      lastHit = millis();


      if (posHit && poskey) {
        Keyboard.press(poskey);
        Keyboard.release(poskey);
      } else if (negkey) {
        Keyboard.press(negkey);
        Keyboard.release(negkey);
      }
    }
  private:
    const unsigned long debounceTime = 500;
    unsigned long lastHit = 0;
    bool posHit;
};


void failsafe() {
  for (;;) {} // Just going to hang out here for awhile :D
}


void typeName(int pin) {
  if (digitalRead(pin)) {return;}
  if (pin == N1_PIN) {
    Keyboard.println(N1_STRING);
  } else if (pin == N2_PIN) {
    Keyboard.println(N2_STRING);
  }
  delay(1500);
}


// Button objects, organized in array
button buttons[] = {
  {RS_KEY, RS_PIN},
  {LS_KEY, LS_PIN},
  {R_KEY, R1_PIN},
  {R_KEY, R2_PIN},
  {EC_KEY, EC_PIN},
  {UP_KEY, UP_PIN},
  {RT_KEY, RT_PIN},
  {LF_KEY, LF_PIN},
  {DN_KEY, DN_PIN},
};


sensor sensors[] = {
  {SENSE_X_POSITIVE_KEY, SENSE_X_NEGATIVE_KEY, SENSE_X_PIN, SENSE_X_REF, SENSE_X_THRESHOLD},
  {SENSE_Y_POSITIVE_KEY, SENSE_Y_NEGATIVE_KEY, SENSE_Y_PIN, SENSE_Y_REF, SENSE_Y_THRESHOLD},
  //{SENSE_Z_POSITIVE_KEY, SENSE_Z_NEGATIVE_KEY, SENSE_Z_PIN, SENSE_Z_REF, SENSE_Z_THRESHOLD},
};


const uint8_t NumButtons = sizeof(buttons) / sizeof(button);
const uint8_t NumSensors = sizeof(sensors) / sizeof(sensor);
const uint8_t ledPin = 17;




void setup() {
  // Safety check. Ground pin #1 (RX) to cancel keyboard inputs.
  pinMode(1, INPUT_PULLUP);
  if (!digitalRead(1)) {
    failsafe();
  }
  // Set LEDs Off. Active low.
  pinMode(ledPin, OUTPUT);
  digitalWrite(ledPin, HIGH);
  TXLED0;
  for (int i = 0; i < NumButtons; i++) {
    pinMode(buttons[i].pin, INPUT_PULLUP);
  }
  pinMode(N1_PIN, INPUT_PULLUP);
  pinMode(N2_PIN, INPUT_PULLUP);
}


void loop() {
  for (int i = 0; i < NumButtons; i++) {
    buttons[i].update();
  }
  for (int i = 0; i < NumSensors; i++) {
    sensors[i].tilt();
  }
  typeName(N1_PIN);
  typeName(N2_PIN);
}

Alles anzeigen

C

#include <Keyboard.h>
/*  
Sensor Test
*/
// ---------------------------------
// KEYS
#define SP_KEY 0x20
#define SENSE_X_POSITIVE_KEY SP_KEY
#define SENSE_X_NEGATIVE_KEY SP_KEY
#define SENSE_Y_POSITIVE_KEY SP_KEY
#define SENSE_Y_NEGATIVE_KEY 0
#define SENSE_Z_POSITIVE_KEY 0
#define SENSE_Z_NEGATIVE_KEY 0


// PINS
#define SENSE_X_PIN A3
#define SENSE_Y_PIN A2
#define SENSE_Z_PIN A1


// Sensor values
// Referenzwert ist der Wert in Ruhe, Threshold ab welchem Ausschlag es reagieren soll
#define SENSE_X_REF 0
#define SENSE_X_THRESHOLD 10
#define SENSE_Y_REF 0
#define SENSE_Y_THRESHOLD 10
#define SENSE_Z_REF 0
#define SENSE_Z_THRESHOLD 10


// ---------------------------------


class sensor {
  public:
    const char poskey;
    const char negkey;
    const int pin;
    const int ref;
    const int minBump;
    sensor(int pk, int nk, int p, int r, int mB) : poskey(pk), negkey(nk), pin(p), ref(r), minBump(mB){}
    int readraw() {
      return analogRead(pin);
    }
    bool hit() {
      int a = readraw();
      Serial.println(a);
      posHit = a > ref;
      return abs(a - ref) > minBump;
    }
    void tilt() {
      if (!(hit()) || (millis() - lastHit <= debounceTime)) {return;}
      lastHit = millis();


      if (posHit && poskey) {
        Serial.println("positive hit");
      } else if (negkey) {
        Serial.println("negative hit");
      }
    }
  private:
    const unsigned long debounceTime = 500;
    unsigned long lastHit = 0;
    bool posHit;
};


void failsafe() {
  for (;;) {} // Just going to hang out here for awhile :D
}


sensor sensors[] = {
  {SENSE_X_POSITIVE_KEY, SENSE_X_NEGATIVE_KEY, SENSE_X_PIN, SENSE_X_REF, SENSE_X_THRESHOLD},
  //{SENSE_Y_POSITIVE_KEY, SENSE_Y_NEGATIVE_KEY, SENSE_Y_PIN, SENSE_Y_REF, SENSE_Y_THRESHOLD},
  //{SENSE_Z_POSITIVE_KEY, SENSE_Z_NEGATIVE_KEY, SENSE_Z_PIN, SENSE_Z_REF, SENSE_Z_THRESHOLD},
};


const uint8_t NumSensors = sizeof(sensors) / sizeof(sensor);
const uint8_t ledPin = 17;




void setup() {
  // Safety check. Ground pin #1 (RX) to cancel keyboard inputs.
  pinMode(1, INPUT_PULLUP);
  if (!digitalRead(1)) {
    failsafe();
  }
  // Set LEDs Off. Active low.
  pinMode(ledPin, OUTPUT);
  digitalWrite(ledPin, HIGH);
  TXLED0;
}


void loop() {
  for (int i = 0; i < NumSensors; i++) {
    sensors[i].tilt();
  }
}

Alles anzeigen

So, jetzt bin ich gespannt ob der Code funktioniert

the ratman

Zitat

wollte in meiner freien Zeit dann nicht noch mehr vor dem Computer sitzen.

anti-nerd?

o.k. also mal code 2 zum testen und dann code 1 mit den werten von code 2 + den entsprechenden tasten.

Zitat

Kannst du die Schubser von links/rechts auf einzelne Tasten legen? In dem Fall sollte es mit dem folgenden Code funktionieren.

du meinst jetzt die flipper? tun sie eh schon pin 2 und pin 3. bin grade verwirrt.

Seppl1

Ne, ich meine das "rütteln" von links/rechts. Du hattest geschrieben, das ist standardmäßig "lshift+strg" und "rshift+strg". Kannst du das auf jeweils eine einzelne Taste abändern?

the ratman

jo, kann ich

ist jetzt n (links) und m (rechts) "space" bleibt für vorne, wenn's genehm ist *g*

so, hab nun teil 2 geladen ...
was sollte da wo passieren?
zumindest ausgabe in meinem notepad bleibt leer

die keys hab ich wie folgt angepasst:
// KEYS
#define SP_KEY 0x20
#define SENSE_X_POSITIVE_KEY 0x6D
#define SENSE_X_NEGATIVE_KEY 0x6E
#define SENSE_Y_POSITIVE_KEY SP_KEY
#define SENSE_Y_NEGATIVE_KEY 0
#define SENSE_Z_POSITIVE_KEY 0
#define SENSE_Z_NEGATIVE_KEY 0
ansonsten ist alles deins

hab nun den eigentlicken sketch mit den 2 neuen keys hoch geladen. nur, falls das hilft:
sofort tickt der los
notepad: "m mm m m m m m m mm m m m mm mm mm m mm m m mm m"
mit folgenden keys (sonst nix angegriffen):
// KEYS
#define RS_KEY 0x85
#define LS_KEY 0x81
#define R_KEY 0xB0
#define EC_KEY 0xB1
#define XX_KEY 0x00
#define UP_KEY 0xDA
#define RT_KEY 0xD7
#define LF_KEY 0xD8
#define DN_KEY 0xD9
#define SP_KEY 0x20
#define PL_KEY 0x6E
#define PR_KEY 0x6D
#define SENSE_X_POSITIVE_KEY PR_KEY
#define SENSE_X_NEGATIVE_KEY PL_KEY
#define SENSE_Y_POSITIVE_KEY SP_KEY
#define SENSE_Y_NEGATIVE_KEY 0
#define SENSE_Z_POSITIVE_KEY 0
#define SENSE_Z_NEGATIVE_KEY 0

Seppl1

Also, dass es ständig "m" schreibt, liegt sicher an den noch nicht gesetzten Referenzwerten.

Der 2. Code schreibt nur in die Konsole, die Textdatei würde nämlich sehr schnell sehr lang werden. Wenn dir das aber lieber ist musst du nur in Zeile 44, 53 und 55 Serial.println durch Keyboard.println ersetzen.

Der 2. Code wird nach dem einstecken sofort anfangen ständig eine Zahl zu schreiben. Wenn die Tastatur ruhig steht sollte das immer (nahezu) der gleiche Wert sein, den trägst du dann als Referenzwert für die x-Achse ein. (Im ersten Code Zeile 46, im 2. Code Zeile 22). Solange dieser Referenzwert noch nicht stimmt, wird es auch ständig "negative hit" oder "positive hit" schreiben.
Danach kannst du testen, ob der Grenzwert zum triggern i.O. ist, dafür am Besten in Zeile 44 (2. Code) das Serial.println (bzw. Keyboard.println) auskommentieren. Dann sollte es nur bei einem erkannten Hit entsprechend "positive/negative hit" schreiben. Wenn dir das zu früh/spät kommt den Wert in Zeile 47 (1. Code) bzw. 23 (2. Code) ändern.

Dann machst du das Gleiche nochmal für die y-Achse, also im 2. Code in Zeile 69/70 die x-Achse auskommentieren und y aktivieren.

the ratman

nönö, mir is lieber, was du empfiehlst, ich wusste ja nur nicht wie und wo ...

wird a bissi dauern, hab grad ein küchenprojekt von der holden übergeben bekommen

Seppl1

Spüldienst?

the ratman

nö, wir mussten gestern in der küche wegen glasbruches mit inhalt die abschlussleisten am boden weg machen und ich hab festgestellt, dass da eine schief drinnen war, weil der küchen-onkel wohl zu faul zum anpassen unterm geschirrspüler war.
hat jetzt ja 8 jahre keine sau interessiert, aber nu weis SIE es ... also darf ich mir überlegen, wie ich mit einer altersschwachen stichsäge, einem noch älteren sägeblatt und exakt 1 holzfeile da was grades abgeschnitten krieg *g*.
und - ich darf natürlich nur in ihrem beisein in IHRER küche was machen. nicht, dass ich schief schneide, weil das würd da unten eh keiner sehen, aber sie wissen *g*. blöd nur, dass sie nebenbei auch noch kunden betreuen muss ... ich muss aber sagen: ist schön in der küche, fast wie auf der couch.

the ratman

so, is ja doch zeit.
notiz:

// Referenzwert ist der Wert in Ruhe, Threshold ab welchem Ausschlag es reagieren soll
#define SENSE_X_REF 360
#define SENSE_X_THRESHOLD 40
#define SENSE_Y_REF 377
#define SENSE_Y_THRESHOLD 40
#define SENSE_Z_REF 291
#define SENSE_Z_THRESHOLD 10

wobei z gar nicht reagiert, egal, was ich eintrage
x rennt super, y auch

weiteres später ...

und noch mehr zeit *g*:
eigentliches programm sieht jetzt so aus, damit wir den gleichen stand haben:

Code

// ---------------------------------
// KEYS
#define RS_KEY 0x85
#define LS_KEY 0x81
#define R_KEY 0xB0
#define EC_KEY 0xB1
#define XX_KEY 0x78
#define UP_KEY 0xDA
#define RT_KEY 0xD7
#define LF_KEY 0xD8
#define DN_KEY 0xD9
#define SP_KEY 0x20
#define PL_KEY 0x6E
#define PR_KEY 0x6D            
#define SENSE_X_POSITIVE_KEY PR_KEY
#define SENSE_X_NEGATIVE_KEY PL_KEY
#define SENSE_Y_POSITIVE_KEY SP_KEY
#define SENSE_Y_NEGATIVE_KEY 0
#define SENSE_Z_POSITIVE_KEY 0
#define SENSE_Z_NEGATIVE_KEY 0


// STRINGS
#define N1_STRING "bastet"
#define N2_STRING "ratman"
// PINS
#define RS_PIN 2
#define LS_PIN 3
#define R1_PIN 4
#define N1_PIN 5
#define N2_PIN 6
#define R2_PIN 7
#define EC_PIN 8
#define XX_PIN 9
#define SENSE_X_PIN A3
#define SENSE_Y_PIN A2
#define SENSE_Z_PIN A1
#define UP_PIN 15
#define RT_PIN 14
#define LF_PIN 16
#define DN_PIN 10


// Sensor values
// Referenzwert ist der Wert in Ruhe, Threshold ab welchem Ausschlag es reagieren soll
#define SENSE_X_REF 360
#define SENSE_X_THRESHOLD 50
#define SENSE_Y_REF 377
#define SENSE_Y_THRESHOLD 40
#define SENSE_Z_REF 291
#define SENSE_Z_THRESHOLD 10

Alles anzeigen

und

Code

// Button objects, organized in array
button buttons[] = {
  {RS_KEY, RS_PIN},
  {LS_KEY, LS_PIN},
  {R_KEY, R1_PIN},
  {R_KEY, R2_PIN},
  {EC_KEY, EC_PIN},
  {UP_KEY, UP_PIN},
  {RT_KEY, RT_PIN},
  {LF_KEY, LF_PIN},
  {DN_KEY, DN_PIN},
  {XX_KEY, XX_PIN},

Alles anzeigen

funzt auch nach mehrmaligen einstecken jetzt. generell scheint mir das also mal fertig zu sein.
fehlt nur mehr die kühr mit dem aufruf meiner bat-datei, dann bist du entlassen und kriegst ein fleißbienchen in deinen heftchen von mir *g*
also simpler, einmaliger start von C:\Users\the ratman\Spiele\pbfx3.bat , sobald das ding strom kriegt.

auf jeden fall (wieder mal) VIELEN, VIELEN dank an dich!!!!

the ratman

@Seppl1 eine extradumme frage hab ich auch noch.

dir sind nicht zufällig dehnmesstreifen (oder ähnliches) in erschwinglich preislicher art bekannt, die man an so 'nen arduino dran machen könnte?

und einfach, weil ich dich lachen hören will:
wegen meines start-programms - müsste da einfach als zeile 1 "Keyboard.println(" C:\Users\the ratman\Spiele\pbfx3.bat");" rein?

don

Ich bin da auch kein Experte, aber das wird mMn nicht gehen.
Das wäre ja schon "gefährlich", wenn durch einstecken einer Tastatur automatisch ein Programm gestartet wird.

the ratman

öhm?
normal baust du dir ne autorun.inf auf deinen stick/hdd/... damit irgendwas gleich mal passiert. is ja auch nur n stick, wenn man's ein bissi offener sieht.

ich hab mein bspl. oben aus 'nem forum. die arbeiten aber mit einer anderen library und was die sonst so schreiben kapier ich sowieso ned.
das es geht ist also klar. nur wie in meiner situation dann eher weniger *g* aber dafür gibts ja dann den seppl1 ... *seppl herbeibete*

the ratman

ich hab noch ein problem ausgemacht:

wenn der sensor auslöst, was er grade wirklich super macht, dann drückt quasi der arduino z.b. die space-taste nicht lange genug.
die "debounceTime" hilft mal nix - war schon auf 50ms anstelle deiner 500. ist dem flipper aber sowas von egal ... es wird quasi schneller "entruckelt" als der flipper drauf reagiert *g*
kann ich das wo einstellen?

ich hab jetzt auch 2 räucherstäbchen angezündet ... wenn du magst, mit beigaben!

btw @don
ich erinnere mich noch an irgend ein tool, mit dem man z.b. das emulieren einer tastatur per usb-stick verhindern konnte, wegen böser skriptkiddys.
hast schon recht wegen "böse", aber das ist mein compi eh gewohnt von mir *g*

Seppl1

Also, der Reihe nach:

Zitat von the ratman

dir sind nicht zufällig dehnmesstreifen (oder ähnliches) in erschwinglich preislicher art bekannt, die man an so 'nen arduino dran machen könnte?

Nicht wirklich. Piezos erzeugen ja eine Spannung, wenn sie Druck abbekommen bzw. minimal verformt werden. Die werden bei Arduinos z.B. als Vibrationssensor verwendet, aber wenn man da z.B. ein Gummiband befestigen könnte, müsste das eine Spannung abhängig vom Zug am Band ausgeben. Allerdings nur so rein theoretisch.
Wenn du googelst findest du aber bestimmt auch Dehnmessstreifen die man mit nem Arduino auslesen kann.

Zitat von the ratman

wegen meines start-programms - müsste da einfach als zeile 1 "Keyboard.println(" C:\Users\the ratman\Spiele\pbfx3.bat");" rein?

Naja, auf jeden Fall nicht in Zeile 1. Aber wenn man es ans Ende der setup Funktion setzt, wird nichts anderes passieren, als ob du diese Zeichenfolge einfach per Tastatur eintippen und Enter drücken würdest. Also wenn du schon die Kommandozeile offen hast, würde das sogar funktionieren, aber im Allgemeinen nicht. Man müsste aber im Prinzip nur noch per Tastenkürzel die Kommandozeile öffnen, dann könnte das hinhauen.

Zitat von the ratman

wenn der sensor auslöst, was er grade wirklich super macht, dann drückt quasi der arduino z.b. die space-taste nicht lange genug.

Das ist schnell gelöst: Du musst nur zwischen Keyboard.press() und Keyboard.release() in Zeile 101 und 104 jeweils noch eine Zeile mit delay(50); einfügen. Kannst auch mit dem Wert noch etwas rumspielen, das ist einfach wieviele Millisekunden es gedrückt bleibt.

the ratman

thx für die antworten.

zu 1) hab ich schon vor monaten. ging damals um den "handgamer". da waren dms meine eigentliche grund idee. und die verfolgt mich halt immer noch. ich hatte damals aber so gar nix brauchbares gefunden.

zu 2) als nix. gut, ich heul 5 min. und vergiss es dann. wobei ich nicht verstehe, warum ich eine shell aufmachen muss. ich kann ja die bat auch per mausklick anstarten. die kümmert sich dann schon um die shell.

zu 3) wird in kürze probiert ... ich geh mal frech von aus,. dass du beide male meinst. also bei poskey und negkey.

the ratman

hehe, so kommt man langsam auf die probleme ...

x funzt nu super,
für y bräuchte ich bitte noch eine lösung @Seppl1
ich müsste für die achse eine richtung, also pos oder neg ausschalten. hau ich dem ding nämlich eine vor den latz, löst er 2 mal aus. irgendwie auch logisch*.

*) ich schwenke zum auslösen des tilts die tastatur in ihrer aufhängung nach vorne. das ist wohl die eleganteste lösung, ohne wirklich auf die tastatur hauen zu müssen (was bei manch scharfer kante vom druck auch gerne weh tut) *g*

fazit für alle, die sowas nachbauen wollen (und was ich bis jetzt draus gelernt habe):

1) es funzt. besser als ich bei einem prototypen gedacht hätte. bin generell echt zufrieden! vor allem die (programm)technische seite geht wirklich zuverlässig.
2) die metallstangen im dreieck sind echt super. hält bombenfest und das petg drum rum beschwert sich auch bei 'ner harten session nicht. man kann also durchaus auch mal elegant drucken, ohne, dass es wie ein klotz aussehen muss.
aber ...
1) schön alles rund drucken. mir gefällt kantig zwar super, meinen daumen, die dort aufliegen aber nicht.
2) die minimalistischen knopfhalter an den seiten schauen zwar geil aus, aber man weiß nicht wirklich was man mit den daumen machen soll. da würde ich schöne auflageflächen drucken.
am schönsten wäre wohl, würde man die gesamte kante von einem flippertisch bis zu den knöpfen runter nachbauen. ist halt ein bissi groß und wäre dann wohl einfacher mit 'ner breiten, lackierten holzkiste gelöst.
3) mein monitorständer ist "gerade mal so" schwer genug, damit das ding nicht bei jedem tilten im eifer des gefechts durch die gegend fliegt. also auf große masse und standhaftigkeit achten.
4) was ich auch drucken würde, wären gelenke, um die "seitenarme" zusammenklappen, oder ineinander schieben zu können. das ding ist echt sperrig ... ich hab zwar schon einen platz für, hätte ich den nicht, wärs echt schwierig.

Jetzt mitmachen!