Aqara Water Leak Sensor wie konfigurieren?

Zitat von patrick31698

Aber einen Wasseralarm in der Sitemap? Ist das sinnvoll?

kann schon sinnvoll sein. bspw wenn der sensor mal nach nem neustart o.ä. keine verbindung hat. dann siehst du da ob der status UNDEF/NULL ist.

ok dann items und rules NICHT aus meinem letzten beitrag nehmen. hier kommt die finale version. damit werden dann auch nochmals die namen aller alarmauslösenden wassersensoren in der erinnerungsrule gesendet.

sitemap:

Text item=Water_Sensor1_leak
Text item=Water_Sensor2_leak

items:

Group:Switch:OR(ON, OFF) Wassersensor
Switch      Water_Sensor1_leak          "Wassersensor Aquarium [MAP(Wassersensor.map):%s]"       <water>    (Wassersensor)          {channel="mihome:sensor_wleak_aqxxxxxxxxxxx:xxxxxxxxxxxxxxx:leak"}
Switch      Water_Sensor2_leak          "Wassersensor Küche [MAP(Wassersensor.map):%s]"          <water>    (Wassersensor)         {channel="mihome:sensor_wleak_aqyyyyyyyyyyy:yyyyyyyyyyyyyyy:leak"}

datei runterladen, entpacken und Wassersensor.map in den transform ordner von openhab schieben /etc/openhab/transform Wassersensor.zip
achtung das "Map Transformation" binding muss in openhab installiert sein.

rule 1:

rule "Wasseralarm"
    when   
        Member of Wassersensor changed to ON  
    then
        val telegramAction = getActions("telegram","telegram:telegramBot:Telegram_Bot")
        val sensor  = triggeringItem.label
            Alarm_repeat.sendCommand(ON)
            if (Patrick.state == ON){
               Alexa_Sprachausgabe.sendCommand("Achtung! " + sensor + " hat Alarm ausgelöst!")
            }
            if (Patrick.state == OFF){
               telegramAction.sendTelegram("Achtung! " + sensor + " hat Alarm ausgelöst!")
            }
    end

rule 2

rule "Wasseralarm Erinnerung"
when   
    Item Alarm_repeat changed from ON to OFF  
then
    val telegramAction = getActions("telegram","telegram:telegramBot:Telegram_Bot")
    val sensor = Wassersensor.members.filter[ i | i.state == ON ].map[ label ].reduce[ s, label | s + ", " + label ]
        if (Wassersensor.state == ON && Patrick.state == ON){
            Alarm_repeat.sendCommand(ON)
            Alexa_Sprachausgabe.sendCommand("Achtung! " + sensor + " ist noch aktiv!")
        }
        if (Wassersensor.state == ON && Patrick.state == OFF){
            Alarm_repeat.sendCommand(ON)
            telegramAction.sendTelegram("Achtung! " + sensor + " ist noch aktiv!")
        }
end

Gruppe Wassersensor angelegt?

Zitat von patrick31698

Aah da muss ich noch mal schauen, in der ersten Version hieß die Gruppe Wassersensoren, in der zweiten Wassersensor. Vielleicht habe ich das nicht geändert.

möglich, deswegen schrieb ich oben ja:

Zitat von horschte

ok dann items und rules NICHT aus meinem letzten beitrag nehmen. hier kommt die finale version.

nenne die gruppe gleich mal so
Group:Switch:OR(ON, OFF) Wassersensor

Zitat von patrick31698

Juhu! Fehler gefunden!

und wars die fehlende bzw falsch benannte Gruppe?

Zitat von patrick31698

Wenn ich den Alarm auf allen Echos ausgeben will, packe ich die Sprachausgabe items auch in eine Gruppe und lasse die Gruppe den Alarm ausgeben?

Genau. Die TTS Channels in eine Gruppe und dann funktioniert das auch.

na dann....auf zum nächsten projekt